Verschiedene Bildformate automatisiert ordnen

Individuum · 21. Oktober 2024

Hallo zusammen,

ich benötige ein kleines Batch Skript für die Windows11 Umgebung, welches mit automatisiert Hochkant / Querformat Bilder ordnet.

Dabei liegen alle Bilder im Ordner X. Die jeweilige Ausrichtung (Querformat und Hochkant) haben immer dieselbe Größe.

Also:

Wenn Bild die Abmessungen A x B hat, dann Ordner Hochkant.

Wenn Bild die Abmessung C x D hat, dann Ordner Querformat.

Habe bereits mit magick identify gearbeitet. Hier werden mir aber, zumindest meinem Verständnis nach, nicht die richtigen Werte ausgegeben, wodurch meine Automatisierung nicht gelingt:

Exemplarisch 2 Bilder:

pasted-from-clipboard.png

Und dazu die Ausgabe des Tools beim auslesen der Bilder:

pasted-from-clipboard.png

Ich vermute, ich habe hierbei ein Verständnisproblem des Tools, oder?

malE · 21. Oktober 2024

Von ChatGPT

Batch

@echo off
setlocal enabledelayedexpansion

:: Definiere Ordner
set landscapeDir=Landscape
set portraitDir=Portrait

:: Erstelle Ordner, falls sie noch nicht existieren
if not exist "%landscapeDir%" mkdir "%landscapeDir%"
if not exist "%portraitDir%" mkdir "%portraitDir%"

:: Schleife durch alle .jpg und .jpeg Dateien im aktuellen Verzeichnis
for %%f in (*.jpg *.jpeg) do (
    echo Verarbeite Bild: %%f

    :: Dimensionen mit magick identify auslesen
    for /f "tokens=3 delims= " %%d in ('magick identify "%%f"') do (
        set "dimensions=%%d"
        for /f "tokens=1,2 delims=x" %%a in ("!dimensions!") do (
            set "width=%%a"
            set "height=%%b"

            :: Ausgabe der Bildgröße
            echo Bildgroesse: Width=!width! Height=!height!

            :: Breite und Höhe vergleichen
            if !width! gtr !height! (
                echo Bild ist im Querformat. Verschiebe nach %landscapeDir%...
                move "%%f" "%landscapeDir%"
            ) else (
                echo Bild ist im Hochformat. Verschiebe nach %portraitDir%...
                move "%%f" "%portraitDir%"
            )
        )
    )
)

:: Pause hinzufügen, damit das Fenster offen bleibt
echo Verarbeitung abgeschlossen!
pause

endlocal

Alles anzeigen

Individuum · 21. Oktober 2024

Habe schon mit ChatGPT geschrieben und einige Scripte getestet.

Das bringt aber nichts, wenn magick mir inkorrekte Werte liefert (siehe oben) - es wurden immer alle Bilder in einen Ordner sortiert.

malE · 21. Oktober 2024

Hast du das Skript überhaupt getestet? Bei mir klappts.

Edgar · 21. Oktober 2024

Wäre es für dich möglich, die beiden Bilder aus deinem Beispiel hochzuladen?

Möglich wäre, dass die Abmessung stimmt, die Orientierung des Bildes aber auf Quer/Hoch verändert wurde (und diese in der Abmessung nicht greift?)

Individuum · 21. Oktober 2024

Zitat von malE

Hast du das Skript überhaupt getestet? Bei mir klappts.

Wie gesagt, gibt mir magick die falschen Werte aus. Habe es aber auch gerade getestet. Leider werden wieder beide Bilder in einen Ordner verschoben; in den Landscape Ordner.

Zitat von Edgar

Wäre es für dich möglich, die beiden Bilder aus deinem Beispiel hochzuladen?
Möglich wäre, dass die Abmessung stimmt, die Orientierung des Bildes aber auf Quer/Hoch verändert wurde (und diese in der Abmessung nicht greift?)

Na klar,:

KRA07296.jpg

KRA07201.jpg

Edgar · 21. Oktober 2024

Die Bilder sind natürlich komprimiert. Aber bei mir gibt magick die Auflösung richtig zurück.

pasted-from-clipboard.png

Individuum · 27. Oktober 2024

Hallo zusammen,

zwecks Lösungsfindung ein kurzer Nachtrag:

Bei mir musste ich mit einem Paramater arbeiten, um das zu ermöglichen.

Der Befehl sieht wie folgt aus:

Code

magick wonderfit.JPG -auto-orient -format "%[fx:w>h?1:0]" info:

Falls es jemand braucht, hier das .bat Skript:

Code

@echo off
setlocal enabledelayedexpansion

set "inputDir=C:\Pfad\zum\verzeichnis"
set "outputDirLandscape=C:\Pfad\zum\verzeichnis\Querformat"
set "outputDirPortrait=CC:\Pfad\zum\verzeichnis\Hochkant"

for %%f in ("%inputDir%\*.JPG") do (
    echo Verarbeite Datei: %%f

    REM Verwende ImageMagick, um die Größe zu bestimmen
    for /f %%o in ('magick "%%f" -auto-orient -format "%%[fx:w>h?1:0]" info:') do (
        set orientation=%%o
    )

    REM Datei basierend auf der Größe verschieben
    if "!orientation!"=="1" (
        echo Verschiebe Datei nach %outputDirLandscape%
        move "%%f" "%outputDirLandscape%"
    ) else (
        echo Verschiebe Datei nach %outputDirPortrait%
        move "%%f" "%outputDirPortrait%"
    )
)

echo Fertig
pause

Alles anzeigen

Danke für eure Hilfe

Quelle: https://github.com/ImageMagick/ImageMagick/discussions/7710